ABAP Development

Adding custom fields to the Purchase Order transaction ME21N HEADER & ITEM LEVEL.

Prudhvi Choudary — Tue, 21 May 2013 05:29:08 GMT

I searched for Enhancements for ME21N to add custom fields . I found lot of examples unfortunately i didn't come across complete Step by Step Process.So i decided to give a elaborate document.

Enhancement used for ME21N , ME22N , ME23N is MM06E005.

1) If we know the Enhancement name we can directly use it or we can search it in SMOD Transaction.

2) T code to implement Enhancement Project is CMOD.

Give Project name and click CREATE push button.

Give short text and select COMPONENTS push button.

In this screen we can find Function Exit, Screen Exit and Include tables.

For HEADER LEVEL - For adding Custom Tabs, Custom fields in Header level .

EXIT_SAPMM06E_006 - Export Data to Customer Sub screen for Purchasing Document Header (PBO)

This Function Exit is PBO (Process before output). We can add custom logic in this Exit.

Process : Double click on EXIT_SAPMM06E_006 Go to SOURCE CODE tab and you will find INCLUDE file . double click the INCLUDE file and add your

custom code.

INCLUDE ZXM06U36 .

EXIT_SAPMM06E_007 - Export Data to Customer Sub screen for Purchasing Document Header (PAI)

This Function Exit is PBO (Process before output). We can add custom logic in this Exit.

Process : Double click on EXIT_SAPMM06E_007 Go to SOURCE CODE tab and you will find INCLUDE file . double click the INCLUDE file and add your

custom code.

INCLUDE ZXM06U38 .

For ITEM LEVEL - For adding Custom Tabs, Custom fields in Item level .

EXIT_SAPMM06E_016 : Export Data to Customer Sub screen for Purchasing Document Item (PBO).

EXIT_SAPMM06E_018 : Import Data from Customer Sub screen for Purchasing Document Item

Before Creating Screen.

Create STRUCTURE with Required Fields in custom includes CI_EKKODB and CI_EKPODB

CI_EKKODB - Header Data.

CI_EKPODB-Item Data.

---> Now in Screen Exit Section.

use SAPMM06E this is Program Name.

Go to SE38-- Create Program by giving name SAPMM06E.

Go to SE51-- Create Sub-Screen with Screen Number 0111 ( Check Sub-Screen Box) .

----Now Adding Required Code----

Function Exit :
EXIT_SAPMM06E_016 - PBO

Include File:
INCLUDE ZXM06U41 .

Function Exit :

EXIT_SAPMM06E_018 - PAI

Include File:
INCLUDE ZXM06U40 .

This code is to Update Data Base Table EKPO.

Now Coding Part is Completed.

Go to ME21N - In ITEM LEVEL You will find CUSTOMER DATA Tab. In that Tab you will find COST CENTER Field.

EKPO TABLE : CHECK THE DATA.

Same Steps you can follow for adding FIELDS in HEADER LEVEL .

Global Data in ABAP OO Programs

Katan Patel — Tue, 21 May 2013 02:19:59 GMT

I decided to spend a bit of time looking at some of the blogs being published out on SCN as I found myself with a bit of time. Unfortunately I found a lot of examples of poor quality coding, obsolete techniques and non-nonsensical use of OO programming.

As many people are pushing to learn the latest technologies, unfortunately there are many who have not yet grasped many of the fundamental principles of good quality coding. More often than not I have found that having a solid understanding of the syntax and the basic design principles outlined by the good old gang of four has helped me to quickly get up to speed with new advances in technology. There is no point trying to run, before you can walk and eventually it shows in the work you deliver. Testament to this is the WebDynpro developers that embed business logic in the Views of their WebDynpro components or the OO Developers that use classes in the same way they used to use function modules or subroutines.

If you think you are in the above category, then I urge you to go back and learn the basics. There is nothing to be ashamed of. I recently did it myself. Having been persecuted for so many years for trying to use OO techniques that I learnt at university (as it was not fair to other developers who could not code in OO) , I brushed off my old books and gemmed up.

One of the key principles in programming is called the "Separation of Concerns". So one of the first things that breaks this principle is the use of global data. I'm sure you have come across a piece of code in a massive program in a huge subroutine and had a mental breakdown deciphering what the impact of your change is going to be. Well if you modularise your code, preferably in OO, you have a lot less to worry about.

The time for using global program variables (yes and even in report writing) can and should pretty much come to an end. Below is a little template report you can use in your day to day ABAP reporting requirements, which I think exemplifies the usage of passing references and minimal use of the global reference.

*&---------------------------------------------------------------------*
*& Report ZKP_TEMPLATE_REPORT
*&
*&---------------------------------------------------------------------*
*& A very simple MVC template for creating reports.
*& Note the distinct lack of global variables in the main program and
*& even in my classes. It is far better to pass references into methods,
*& then keep track of everything globally.
*&
*&---------------------------------------------------------------------*

REPORT zkp_template_report.
*----------------------------------------------------------------------*
*       CLASS zcl_report_model DEFINITION
*----------------------------------------------------------------------*
* This is a really simplistic model but you could work with your own
* model objects and better incorporate inheritance if required,
* to better encapsulate your business logic
*----------------------------------------------------------------------*
CLASS zcl_report_model DEFINITION.
   PUBLIC SECTION.
     " Shared type elements that are reused globally in my application
     " are placed here in the model
     TYPES: ty_carrid   TYPE RANGE OF s_carr_id,
            ty_currcode TYPE RANGE OF s_currcode,
            tty_scarr   TYPE STANDARD TABLE OF scarr WITH KEY carrid.

     METHODS: get_data IMPORTING im_carrid       TYPE zcl_report_model=>ty_carrid
                                 im_currcode     TYPE zcl_report_model=>ty_currcode
                       RETURNING value(re_scarr) TYPE tty_scarr.

   PRIVATE SECTION.
     " This is the only piece of global data I use in my application
     " it exists only as long as I have a reference to an instance of
     " this class in my program
     DATA: gt_scarr TYPE tty_scarr.

ENDCLASS.                    "zcl_report_model DEFINITION

*----------------------------------------------------------------------*
*       CLASS zcl_report_view DEFINITION
*----------------------------------------------------------------------*
* Your view is really how you intend to present the information. This
* class is abstract and so is the method implying you need to redefine
* it. (Hence no implementation required)
* You may want to render your view in different ways ALV, FILE, EMAIL
*----------------------------------------------------------------------*
CLASS zcl_report_view DEFINITION ABSTRACT.
   PUBLIC SECTION.
     METHODS: display_data ABSTRACT IMPORTING im_scarr TYPE zcl_report_model=>tty_scarr.
ENDCLASS.                    "zcl_report_view DEFINITION

*----------------------------------------------------------------------*
*       CLASS zcl_report_view_alv DEFINITION
*----------------------------------------------------------------------*
* So here is my new class that will implement the display method
* using an ALV. You can do a lot here with the SALV class for
* displaying data, but this will be very simple.
*----------------------------------------------------------------------*
CLASS zcl_report_view_alv DEFINITION FINAL INHERITING FROM zcl_report_view.
   PUBLIC SECTION.
     METHODS: display_data REDEFINITION.
ENDCLASS.                    "zcl_report_v

*----------------------------------------------------------------------*
*       CLASS zcl_report_controller DEFINITION
*----------------------------------------------------------------------*
* This class will be used to handle the flow of the program. Passing
* information from the views and requesting data from the model.
* No business logic should be placed here
*----------------------------------------------------------------------*
CLASS zcl_report_controller DEFINITION ABSTRACT FINAL.
   PUBLIC SECTION.
     " Import all the report selection variables into the controller method
     " for executing the report
     CLASS-METHODS: execute_report
                      IMPORTING im_carrid   TYPE zcl_report_model=>ty_carrid
                                im_currcode TYPE zcl_report_model=>ty_currcode.

ENDCLASS.                    "zcl_report_controller DEFINITION

" I need a global data statement for my selection option
" I could create a generic select-option by adding the
" name in brackets, however I lose the benefits from the data dictionary
" Search helps etc in my selection screen
" Beyond this I will not use this reference again.
" It's not ideal but reporting was never going to be 100% OO
DATA: gt_scarr TYPE scarr.

" Replace these with your report variables
SELECT-OPTIONS: s_carrid FOR gt_scarr-carrid,
                 s_curcod FOR gt_scarr-currcode.

START-OF-SELECTION.
   " Now kick off the report logic
   zcl_report_controller=>execute_report( im_carrid   = s_carrid[]
                                          im_currcode = s_curcod[] ).

*----------------------------------------------------------------------*
*       CLASS zcl_report_controller IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS zcl_report_controller IMPLEMENTATION.
   METHOD execute_report.
     DATA: lo_model    TYPE REF TO zcl_report_model,
           lt_scarr    TYPE zcl_report_model=>tty_scarr,
           lo_disp     TYPE REF TO zcl_report_view,
           lo_disp_alv TYPE REF TO zcl_report_view_alv.

     CREATE OBJECT lo_model.

" Execute the model method to retrieve the data I need for my report
     lt_scarr = lo_model->get_data( im_carrid   = im_carrid
                                    im_currcode = im_currcode ).

     CREATE OBJECT lo_disp_alv.
" Now output the data via the view
" The reason I have assigned the specialised ALV class reference to the
" generalised view class reference is purely overkill in this example.
" However I can very quickly create a new view class and assign this
" perhaps using a case statement to determine which view to output.
     lo_disp = lo_disp_alv.
     lo_disp->display_data( im_scarr = lt_scarr ).
   ENDMETHOD.                    "execute_report
ENDCLASS.                    "zcl_report_controller IMPLEMENTATION

*----------------------------------------------------------------------*
*       CLASS zcl_report_view IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS zcl_report_view_alv IMPLEMENTATION.
   METHOD display_data.
     DATA: lo_salv_tab TYPE REF TO cl_salv_table,
           lx_salv_msg TYPE REF TO cx_salv_msg,
           lt_scarr    TYPE zcl_report_model=>tty_scarr.

     lt_scarr = im_scarr.

     TRY.
" The SALV classes are excellent for quickly generating output for display
" The factory method here generates a new instance based on my input data.
" I could manipulate the output further prior to display if I need
         cl_salv_table=>factory( IMPORTING r_salv_table = lo_salv_tab
                                 CHANGING t_table      = lt_scarr ).

         lo_salv_tab->display( ).
       CATCH cx_salv_msg INTO lx_salv_msg.
         " You should use better exception handling here. Possibly raise it up
         " to the controller class and deal with an appropriate action there
         MESSAGE e000(zkp) WITH 'An error occurred rendering the results'(001)
                                'as an ALV'(002).
     ENDTRY.
   ENDMETHOD.                    "display_data
ENDCLASS.                    "zcl_report_view IMPLEMENTATION

*----------------------------------------------------------------------*
*       CLASS zcl_report_model IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS zcl_report_model IMPLEMENTATION.
   METHOD get_data.
     DATA: lt_scarr TYPE tty_scarr.

     IF gt_scarr IS NOT INITIAL.
       re_scarr = gt_scarr.
     ENDIF.

     SELECT *
       FROM scarr
       INTO TABLE lt_scarr
       WHERE carrid   IN im_carrid
       AND   currcode IN im_currcode.

     IF sy-subrc = 0.
       re_scarr = gt_scarr = lt_scarr.
     ENDIF.
   ENDMETHOD.                    "get_data
ENDCLASS.                    "zcl_report_model IMPLEMENTATION

At this point I won't be mentioning singleton classes in the context of global data, but they do have their place. And there is a pretty good blog out there discussing this in ABAP.

MACROS in ABAP

Mohammed Yakub Shah — Mon, 20 May 2013 08:02:35 GMT

Well, it is a very old methodology but still useful in some cases..... for those who are not aware....

Macro is just like Sub-routine BUT.... it has some differences.

MACROS needs to be declared before usage, Sub-routines can be called and defined later below in the program.

A macro can be used when we want to use the same set of statement multiple times.

A macro is either local and can be defined as :

DEFINE macro_name.

statements

END-OF-DEFINITION.

The maximum number of parameters that can be passed in a macro are 9.

One of the possible example I could think is easy to understand is field catalog.

DEFINITION.

DEFINE Build_FCat.

itfieldcat-fieldname = &1.

itfieldcat-col_pos = &2.

itfieldcat-seltext_l = &3.

itfieldcat-emphasize = &4.

itfieldcat-outputlen = &5.

append itfieldcat to itfieldcat.

clear itfieldcat.

END-OF-DEFINITION.

USAGE.

Build_FCat 'EBELN' '01' 'PO Number' 'X' 10.

Build_FCat 'EBELP' '02' 'PO Item' ' ' 05.

Build_FCat 'MAKTX' '03' 'Description' ' ' 25.

A macro can be GLOBAL and the best example is the BREAK statement of ABAP.

Global macros are defined in table TRMAC in SAP and can be used as you use the BREAK statement.

Now,

Macros don't belong to the definition part of the program. So you cannot debug them and they don't appear also in the debugger.

The best use would be to put logic that are complex calculations that you don't want to be disturbed in debug mode

Some checks which you want to over ride etc.

But in generalized way if used can save you lot of stuffs like using in QCI calculations for OIL material quantities to group it and get the table directly

Note : SAP recommends to use MACROS only in EXCEPTIONAL cases.

Screen cast of Open XML documents Contents read

Ronen Almog — Thu, 16 May 2013 21:43:36 GMT

Hello.

This is a screen-cast showing

Reading Contents of MS-Word documents ( Open XML documents )

form outside the SAP

into SAP content.

http://www.youtube.com/watch?v=Ratcsce-8qE

Open XML documents are manipulated on the SAP server

without using MS-Word application.

this is done by ABAP objects using Open XML specification.

Ronen Almog

Posting a Goods Movement Document in IS-OIL

Mohammed Yakub Shah — Tue, 14 May 2013 12:48:10 GMT

This blog illustrates the method to post goods movement in IS-OIL.

Almost every one of us have used “BAPI_GOODSMVT_CREATE” to post a material goods movement in SAP. But when we are working in IS-Oil material this BAPI does not work and we end up trying different ways to do the same.

Well SAP has another BAPI for this and I will try to post a 311 movement with the same. I hope this helps in other postings as well.

The BAPI is BAPI_GOODSMVT_CREATE_OIL.

Data Declaration :

     DATA : lw_item       TYPE bapioil2017_gm_itm_crte_01,
        lw_item_param TYPE bapioil2017_gm_itm_crte_param,
        lw_header     TYPE bapioil2017_gm_head_create,
        lw_doc_no     TYPE mkpf-mblnr,
        lt_item       TYPE TABLE OF bapioil2017_gm_itm_crte_01,
        lt_item_param TYPE TABLE OF bapioil2017_gm_itm_crte_param,
        lt_return     TYPE TABLE OF bapiret2.

Passing the Data.

Now most data passing will be similar to our standard way.

Material Document Header.

lw_header-pstng_date = sy-datum.
lw_header-doc_date = sy-datum.

Material Document Item.

lw_item-material      = lw_g_odet-matnr.
        lw_item-move_mat      = lw_g_odet-matnr.
        lw_item-plant         = lw_tankm-plant.
        lw_item-stge_loc      = lw_tankm-sloc.
        lw_item-batch         = lw_oijnomi-charg_o.
        lw_item-val_type      = lc_vatyp.
        lw_item-move_plant    = lw_tankm-plant.
        lw_item-move_stloc    = lc_vsloc.
        lw_item-move_batch    = lw_oijnomi-charg_o.
        lw_item-move_val_type = lc_vatyp.
        lw_item-move_type     = '311'.

lw_item-entry_qnt = lw_tankm-tag_value.
lw_item-entry_uom = lw_tankm-tag_uom.

Posting the Additional Quantities

Now this is the major difference between normal goods movement and IS-Oil goods movement.

In the declared lt_item_param there are two control parameters for posting items with additional quantities:

§ CALCULATEMISSING

§ USEDEFAULTPARAMETERS

There are QCI [Quantity Conversion Interface] parameters which are default specified in configuration if you want to use them you put the USEDEFAULTPARAMETERS parameter value as ‘X’.

Extract from SAP FM Documentation for understanding.

If the value you enter for the CALCULATEMISSING parameter differs from the default value, the system determines all all necessary units of measure for this posting item and calculates the missing quantities. Otherwise you must ensure that the system can access all quantities in all required units of measure through the interface.

We are going to provide values.

For some materials the Air Buoyancy indicator is also a parameter for conversion that can be received from MARC.

        SELECT SINGLE umrsl abfac FROM marc
                              INTO (lw_item_param-conversiongroup,
                                   lw_item_param-airbuoyancyconstant )
                            WHERE matnr = lw_g_odet-matnr
                               AND werks = lw_tankm-werks.

        IF sy-subrc IS INITIAL.
          IF lw_item_param-airbuoyancyconstant IS NOT INITIAL.
            lw_item_param-airbuoyancyindicator = 'X'.
          ENDIF.
        ENDIF.

        lw_item_param-calculatemissing        = 'X'.
        lw_item_param-testtemperature_density = '15.00'.
        lw_item_param-testtemp_density_uom    = 'CEL'.

        lw_item_param-basedensity             = lw_tankm-tag_value.
        lw_item_param-basedensityuom          = lw_tankm-tag_uom.
        lw_item_param-testdensity             = lw_tankm-tag_value.
        lw_item_param-testdensity_uom         = lw_tankm-tag_uom.

lw_item_param-materialtemperature = lw_tankm-tag_value.
lw_item_param-materialtemperature_uom = lw_tankm-tag_uom.

Another important point

There is a mapping between the item and item_param that is line_id they should be same for the item for which the parameter is passed.

ADD 1 TO lw_item_count.
lw_item-line_id = lw_item_param-line_id = lw_item_count.

APPEND lw_item TO lt_item.
APPEND lw_item_param TO lt_item_param.

CLEAR : lw_item,
lw_item_param.

Calling the BAPI

Finally we will call the BAPI to post the Document.

CALL FUNCTION 'BAPI_GOODSMVT_CREATE_OIL'
      EXPORTING
        goodsmvt_header     = lw_header
        goodsmvt_code       = '04'
      IMPORTING
        materialdocument    = lw_doc_no
      TABLES
        goodsmvt_item_01    = lt_item
        goodsmvt_item_param = lt_item_param
        return              = lt_return.

    IF lt_return IS INITIAL
   AND lw_doc_no IS NOT INITIAL.
      CALL FUNCTION 'BAPI_TRANSACTION_COMMIT' .
      MESSAGE s110 WITH lw_doc_no.
    ELSE.

      CALL FUNCTION 'POPUP_WITH_TABLE_DISPLAY_OK'
        EXPORTING
          endpos_col   = 150
          endpos_row   = 15
          startpos_col = 5
          startpos_row = 5
          titletext    = text-002
        TABLES
          valuetab     = lt_return.

    ENDIF.

Create new batch characteristics with values checked and suggested by a function module

Miroslav Oprsteny — Tue, 14 May 2013 12:37:09 GMT

In this example I'll try to show you how to create new characteristics for a material batch. This will include the following steps:

Creation of a function module to check characteristics value (optional)
Creation of a function module to suggest characteristics value - search help (optional)
Creation of new characteristics (CT04)
Creation/modification of a class (CL02)
Object/Class assignment to a class (CL24N or CL20N)
Batch modification with our new characteristics (MCS2N)

1. Creation of a function module to check characteristics value

In the following code you can see very basic check which can of course be much more complex for your specific scenario.

FUNCTION Z_CHECK_050.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(CHARACT_NO) TYPE  CABN-ATINN
*"     REFERENCE(CHARACT) TYPE  CABN-ATNAM
*"     REFERENCE(VALUE) TYPE  CAWN-ATWRT
*"  EXCEPTIONS
*"      NOT_FOUND
*"----------------------------------------------------------------------

" Allow empty value
  check value is NOT INITIAL.

" Just for demonstration purposes we check for fixed values
  if value <> 1 and 
     value <> 2 and
     value <> 3.
    RAISE NOT_FOUND.
  endif.
ENDFUNCTION.

2. Creation of a function module to suggest characteristics value

In the following code I'll create my own field catalog for selection grid to be displayed. We will need a checkbox column (called CHK) which will inform about which values (multiple allowed) are selected

FUNCTION z_check_050_f4.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(CHARACT_NO) TYPE  CABN-ATINN
*"     REFERENCE(CHARACT) TYPE  CABN-ATNAM
*"     REFERENCE(DISPLAY)
*"     REFERENCE(ADDITIONAL_VALUES) TYPE  CABN-ATSON
*"     REFERENCE(MULTIPLE_VALUES) TYPE  RCTMV-ATLIS
*"     REFERENCE(LANGUAGE) TYPE  SY-LANGU
*"     REFERENCE(DISPLAY_WITH_LANGUAGE)
*"  TABLES
*"      VALUES STRUCTURE  RCTVALUES
*"----------------------------------------------------------------------
  TYPE-POOLS : slis.

  CONSTANTS:
      c_werks(50) TYPE c VALUE '(SAPLCHRG)DFBATCH-WERKS'.

  types:
    BEGIN OF ty_data,
      chk(1) type c,
      value type c,      
    END OF ty_data.

  DATA:
    lt_values type TABLE OF ty_data,
    l_werks TYPE  dfbatch-werks,
    lt_fieldcat TYPE slis_t_fieldcat_alv.

  FIELD-SYMBOLS:
    <fs_value> type ty_data,
    <fs_werks>,
    <fs_rctvalue> TYPE rctvalues,
    <fs_fcat> type slis_fieldcat_alv.

  ASSIGN (c_werks) TO <fs_werks>.
  IF sy-subrc EQ 0.
    l_werks  = <fs_werks>.
  ENDIF.

  CHECK l_werks IS NOT INITIAL.

  APPEND INITIAL LINE TO lt_values ASSIGNING <fs_value>.
  <fs_value>-value = '1'.
  APPEND INITIAL LINE TO lt_values ASSIGNING <fs_value>.
  <fs_value>-value = '2'.
  APPEND INITIAL LINE TO lt_values ASSIGNING <fs_value>.
  <fs_value>-value = '3'.      

  APPEND INITIAL LINE TO lt_fieldcat ASSIGNING <fs_fcat>.
  <fs_fcat>-fieldname  = 'CHK'.
  <fs_fcat>-seltext_m  = ''.
  <fs_fcat>-ddictxt(1) = 'M'.

  APPEND INITIAL LINE TO lt_fieldcat ASSIGNING <fs_fcat>.
  <fs_fcat>-fieldname  = 'VALUE'.
  <fs_fcat>-seltext_m  = 'Value'.
  <fs_fcat>-outputlen  = 10.
  <fs_fcat>-ddictxt(1) = 'M'.

  loop at lt_values ASSIGNING <fs_value>.
    READ TABLE values with KEY value = <fs_value>-value TRANSPORTING NO FIELDS.
    if sy-subrc = 0.
      <fs_value>-chk = 'X'.
    ENDIF.
  ENDLOOP.

  CALL FUNCTION 'REUSE_ALV_POPUP_TO_SELECT'
    EXPORTING
      i_title       = 'Allowed values'
      i_selection   = 'X'
      i_zebra       = 'X'
      i_checkbox_fieldname = 'CHK'
      i_tabname     = 'LT_VALUES'
      it_fieldcat   = lt_fieldcat
    TABLES
      t_outtab      = lt_values
    EXCEPTIONS
      program_error = 1
      OTHERS        = 2.

  LOOP AT lt_values ASSIGNING <fs_value> where chk = 'X'.
    READ TABLE values with KEY value = <fs_value>-value TRANSPORTING NO FIELDS.
    if sy-subrc = 0.
*     selected value had already been assigned - no action needed
    else.
*     new value selected -> add it to the list
      APPEND INITIAL LINE TO values ASSIGNING <fs_rctvalue>.
      <fs_rctvalue>-value = <fs_value>-value.
      <fs_rctvalue>-status = 'I'.
    ENDIF.
  endloop.

  LOOP AT values ASSIGNING <fs_rctvalue> where status <> 'I'.
    READ TABLE lt_values with KEY
      value = <fs_rctvalue>-value
      chk      = 'X'
      TRANSPORTING NO FIELDS.
    if sy-subrc <> 0.
*     value was de-selected - we have to delete it
      <fs_rctvalue>-status = 'D'.
    endif.
  ENDLOOP.

ENDFUNCTION.

3. Creation of new characteristics

Run Transaction CT04, enter name of new batch and press CREATE icon

Enter description of the characteristics, set Status to Released, in Format section select your desired format (we'll create multiple values, character type of length 15)

Now we need to assign our check function module to the characteristics - Go to tab Values, click on Other Value Check and select radio with label Funct. module

When prompted, enter name of our check FM - Z_CHECK_050.

Note: The search help function module Z_CHECK_050_F4 is assigned automatically

4. Creation/modification of a class

Run TCode CL02 and create new or edit existing class for class type 022 (Batch). Enter some description (for new class), go to tab Char. and assign our new characteristics ZBM_0050 to class.

5. Object/Class assignment to a class

Run TCode CL24N select class you used in previous step (B0001), class type 022

for new class without existing assignments click on button Only new assignments and select Material
for class with existing assignments just press enter

6. Batch modification with our new characteristics

Run TCode MSC2N and change a batch for given material. You can see that our new characteristics is available

Try to enter some value different from 1,2 or 3 (values defined in our check FM) and press enter

Press F4 and select some values

Press F4 again and check that your previously selected values are already checked.

Now you can just save your batch - we are DONE

Finding Actual function module for a Function Exit

Gopal Nair — Fri, 10 May 2013 07:04:46 GMT

It is common to find customer exits in SAP’s code and Function modules, to accommodate customer specific business rules in SAP provided applications. These exits sometimes are in the form:

Call Customer-Function ‘xxx’, where ‘xxx’ is usually a number. So, how do we know what the actual function module is, where we should put our custom code?

Here is a screen shot of a function module with customer exit:

To find out the actual function module, we will need to know what the main program name is. You can go to the main program using the menu item GO TO –> Main Program

Now, our customer exit name would be:

EXIT_<Progam Name>_<XXX>,

Where
<Program_Name> is the main program name
<XXX>                  is the number next to “Customer-Function”

In this example function module, the main program was : SAPLHRBEN00GENERAL.

Hence, our customer exit will be
EXIT_SAPLHRBEN00GENERAL_022

Common Developer tools - what do you use ?

Gautham Vangaveti — Thu, 09 May 2013 07:02:11 GMT

Hello

This is my first SCN blog and given below are some common developer tools used by most of the technical consultants in SAP.

Developer tools

Data dictionary objects

Reports

Module pool

BDC

Scripts

Smartforms

Classes

Function modules

Bapi

Lsmw

Customer exits

Badi

Implicit and enhancements

BTE

Validations

Substitutions

Custom infotypes

Workflow

Adobe forms

Query

I would like to know if you do use some other new tools for development.

Any suggestions are always welcome.

Thanks and Regards,

Gautham Vangaveti.

Screen cast of Open XML documents Generation

Ronen Almog — Wed, 08 May 2013 19:06:50 GMT

Hello.

this is a screen cast of how to generate

Word Ooxml documents directly from SAP WAS

without any Office Installation!

http://youtu.be/DPg2AYORNjU

Enjoy!

Ronen Almog

Frustrating!

Mike Kerrigan — Wed, 08 May 2013 11:13:49 GMT

Why do SAP Support take so long to provide the simplest of fixes?

Back in January I debugged an issue for a client involving the transfer of delivery documents from R/3 to GTS. After an hour or so I found the issue and told the client that 1 additional line of code was needed. They decided to log the issue with SAP and included my detailed description of the problem and fix to help speed up the correction.

Fast forward three months and SAP have finally provided a solution and guess what, it's exactly the same solution I provided 3 months earlier.

Very frustrating!

Parallel Cursor : Performance for Nested Loops

Mohammed Yakub Shah — Wed, 08 May 2013 10:19:28 GMT

In a lot of scenarios we come across where nesting loops is the only option we have to achieve what we want.

They can be hazardous if not tuned properly and can result in time out dumps and heavy processing time.

The solution : PARALLEL Cursor.

Lets assume a scenario where we are having 3 internal tables one with following structure.

KNA1

Kunnr

Name1 SORTED TABLE by KUNNR

VBRK

Vbeln

Kunag [Sold to will be equal to kunnr].

VBRP

vbeln

posnr

matnr

netwr [SORTED TABLE by VBELN]

Now it becomes tricky as we want to link KNA1 to VBRK and VBRK to VBRP.

Note : This is just to explain a three level nested loop if exact case is considered a read on KNA1 will be better.

Some thumb rules for Parallel Cursor

1. SORTING should be on the field which will part of where clause if you are not using.

Like in this case KNA1 will be on KUNNR

VBRK will be on KUNAG

and VBRP will be on VBELN.

2. Recommended : use of variables to store tabix of the loop process.

Now the solution :

DATA : lv_vbrk_tabix TYPE sy-tabix,

lv_vbrp_tabix TYPE sy-tabix.

SORT it_vbrk BY kunag.

lv_vbrk_tabix = 1.

LOOP AT it_kna1 INTO wa_kna1.

WRITE:/5 'Name : ' , wa_kna1-name1 , ' | ' , wa_kna1-kunnr.

ULINE.

LOOP AT it_vbrk INTO wa_vbrk FROM lv_vbrk_tabix.

IF wa_kna1-kunnr GT wa_vbrk-kunag.

lv_vbrk_tabix = sy-tabix.

EXIT.

ENDIF.

CHECK wa_kna1-kunnr = wa_vbrk-kunag.

WRITE:/10 wa_vbrk-vbeln , wa_vbrk-fkdat.

READ TABLE it_vbrp WITH TABLE KEY vbeln = wa_vbrk-vbeln

TRANSPORTING NO FIELDS.

* AS IT_VBRP is a sorted table on VBELN default BINARY SEATCH will be used.

IF sy-subrc IS INITIAL.

lv_vbrp_tabix = sy-tabix.

ELSE.

CONTINUE.

ENDIF.

LOOP AT it_vbrp INTO wa_vbrp FROM lv_vbrp_tabix.

IF wa_vbrk-vbeln NE wa_vbrp-vbeln.

EXIT.

ENDIF.

WRITE:/15 wa_vbrp-matnr , 50 wa_vbrp-netwr.

ENDLOOP.

These are the 2 possible ways of parallel cursor.

Do comment if any issues or there is a better way...

BINARY SEARCH Removed and SORTED TABLE added Thanks for the input "Mathew Sir"

What about the good old Dynpro?

Thomas WÜRCHER — Tue, 07 May 2013 09:25:58 GMT

Call me conservative, call me old-fashioned, call me unprogressive - but I still don't get it! I'm talking about SAPs User Interface Roadmap and/or Strategy - especially regarding development in and for SAP ERP - the system environment I am most familiar with, so with this disclaimer let's start with some thoughts on UIs, business processes and custom development.

A couple of years ago, the SAP world for its customers and users was so simple! There was the SAP GUI with its now "outdated", proprietary programming model Dynpro for creation of user interfaces. It undoubtedly had an has some major drawbacks - mainly the various limits regarding user interaction and experience, which had mainly been overcome with the introduction of the enjoy controls. Together with the control framework, SAP GUI had again become a environment for efficient, rich, highly integrated user interface development with high performance.

Efficient development: If you take the different use cases for UIs in a ERP system into consideration - reporting via selection screen and list output, creating, editing and displaying business objects and their relations - old UI techniques like selection screens together with its variants in combination with modern controls like ALV, Tree, Split Screen a.s.o. provide a very effective way for the user to handle his or her business data. Simple reports, data maintainence views, complex business transactions (either single screen or multi-step) - everything built with proven, stable technology and high developer efficiency. And - not to forget - if you need/needed a developer or consultant, you always get/got one - try the same for SAP UI5, WDA with FPM or the unspeakable Java-based technologies.
Rich user experience: Okay, I admit that SAP GUI as a frontend is not what the standard iPad user would call fancy or user friendly. But has it to be fancy and is it really not user friendly? SAP GUI was always and is still meant for daily business processes - from mass data processing to handling single business objects. No app experience needed here as far as I can see. Icons and pictures where necessary, colors where needed - e. g. for status display. Right click, double click, Link click, Drag & Drop, menus, context menus - everything available but a colorful UI itself with everything floating, moving, blinking. Does such a fancy UI really add business value to the software-support of a business process? I highly doubt it.
High integration: The main ERP processes are - and as far as I can see will always be - implemented as SAP GUI transactions, from HCM over Financials and Project System to Material Management and Sales. So in case you want to adapt a SAP delivered GUI program you always have the largest variety of enhancement techniques - from the UI itself to the possibilities for user interaction and the ABAP-based functionalities. Create a custom program and provide access to SAP programs? No problem. Call a custom program from a SAP program. The same. Try this with WDA and SAP GUI for HTML and enjoy the experience!
High performance: You don't expect me to compare DIAG with HTTP, do you?

So, the question for me is the following:

Why does SAP push itself and its customers to use Web-based technologies like WDA, FPM, CRM Web UI, SAP UI5, Web Dynpro Java, Guided Procedures, JSF, Adobe Interactive Forms - and what was this SAP Portal-based code generator called again - with more than the half of these programming models called obsolete just some months after the first painful customer implementations set productive?

Why not continue development of core technologies like Dynpro and Control Framework, for which customers have spent lots of money in consulting, development, in- and outsourcing know how and in which they now have to maintain a large code base?

Just my 2 cents!

PS: In case you didn't guess it yet - I just finished my first big project with WDA!

STMS: facing errors when importing transport requests? It's your fault!

Nicolas Busson — Thu, 02 May 2013 09:49:08 GMT

Without any doubt: your fault it is... and not only because obviously you didn't pay enough attention to objects' dependencies when you released your transport requests, but mainly because you didn't take 3 seconds to start transaction SE38 and run report ZCEX_TRDA_START to let the system check those dependencies for you.

Remark: if you do not find this report in your system, that's probably because you missed this blog post:

How-to check dependencies between transport requests

What's new with code exchange project "TRDA - Transport request dependencies analyzer" then?

First of all, the first versions had been developed on SAP Netweaver 7.02 Developer edition which made its use limited to the happy few customers running one of the last versions of SAP Netweaver... Well, I believe this period is over as it has now been backported to SAP NetWeaver 7.0 Trial version:

Two missing classes have been copied from 702 into customer namespace.
Some statements have been adapted: for example every "&&" character has been replaced by the corresponding "CONCATENATE" statement.
ABAP Unit tests have been reviewed.
Etc.

Speaking of which, those ABAP Unit tests have been enhanced to make sure TRDA finds the following dependencies:

Predecessor	Follower
Domain	Data element based on Domain
Data element	Structure with one component based on Data element
Structure	Table type based on Structure
Table type	Function group with one function module using Table type as importing parameter
Function group	Class implementing a method where a function module from Function group is called
Interface	Class implementing Interface
Class	Program using objects of type Class
Enhancement spot	Function module where Enhancement spot is implemented
Enhancement spot	Enhancement spot implementation of Enhancement spot
Function module	Enhancement spot implementation in Function module
Enhancement spot implementation	Composite enhancement implementation containing Enhancement spot implementation
Database table	Enqueue object for Database table
Database table	Search help based on Database table
Database table	Maintenance view for Database table
Search help	Database table where one component is using Search help
Table maintenance view	Generated function group for Table maintenance view

But that's not the only new feature you'll find on TRDA Code exchange project page: this program can now be installed very easily via SAPlink too (provided you follow the corresponding How-to guide available). Note however that this version released as a nugget file doesn't include any ABAP Unit test class to simplify the installation process (but of course all ABAP Unit tests have been passed before creating the nugget).

And even more new features can be found in the Release notes document:

Parameters to influence the scope of the dependency analysis.
Ability to check dependencies that have been added manually in transport request attributes.
New columns to display transport request status in TMS queues.
Ability to exclude successfully imported request.
Ability to start dependency analysis in background.
Etc.

So if you're interested do not hesitate to join the project and give it a try: even if SAP is working on a similar program at the moment, we don't know yet when it's released, and for which SAP Netweaver versions it will be delivered... hence TRDA may still have some fine days ahead of it!

ST01 RFC TRACE: Debugging ABAP RFC via JAVA Webdynpro Screen.

Jitendra Yadav — Tue, 30 Apr 2013 15:58:10 GMT

This Blog will be helpful to find the ABAP RFCs which get called from the Java webdynpro screen

on applying any action on it. Most of the time in many projects client prefer any other technology screen

or JAVA screen as Frontend but for Backend they use ABAP code. If any problem appear on the

Java screen due to ABAP code execution, then the ABAP code should be debugged with the help of debugger .

To search the name of RFC or the problematic code we can use

SAP transaction ST01 ->RFC Trace.

Procedure in short :

Step 1) Go to ST01 and switch ON the trace

Step2) Do the required actions on Java webdynpro screen such as (Press any Button: Save/update/Delete)

Step3) Go to ST01 and switch OFF the trace and Press analysis to see the required RFCs

Step4) Go to SE37 and find the RFC name. on the external debugging , put the break point

Step5) Do the required actions on Java webdynpro screen as done in step 2 and find that the debugger is on.

Procedure in brief:

1) 1) Go to ST01 and switch ON the trace: Tick the RFC Calls check box and Clicked on Trace on button.

2) Here we can see the below Java Webdynpro screen , Fill in it the required fields and

Press GEM button to update the date in Backend (SAP Database tables).

3) The data is updated, we can see a record on Java webdynpro screen. This updation has

happened in SAP database using ABAP code.

4) Again go to transaction ST01 to OFF the trace by pressing TRACE OFF button

And see analysis report by pressing ANALYSIS button.

5) Put the SAP user name , proper date / time fields value and press execute .

6) After Execute below screen will appear. In the Object Column you can see all the RFCs are listed which were hit

by the action applied on java webdynpro screen. The RFC name may be not fully displayed due to limited length

of OBJECT column in the report.

7) Go to transaction SE37 to find the full name of RFC

put the name got from above screen Z_HR_RFC_UDLAAN_* in function module field

press F4 to get its full name, here I got it Z_HR_RFC_UDLAAN_CREATE.

8) Now put the break point in the found RFC Z_HR_RFC_UDLAAN_CREATE .

9) And using menu entry UTILITIES -> SETTINGS set the external debugging on

10) Now go to Java webdynpro screen and do the same actions hown above you will find the debugger is activated

and normally an ABAPer can start debugging.

ASUG Webcast on 'Custom ABAP Development on SAP HANA'

Srini Tanikella — Tue, 30 Apr 2013 06:32:27 GMT

Session Abstract:

With SAP Business Suite and SAP NetWeaver Business Warehouse, two major SAP standard applications have been optimized for leveraging SAP HANA as primary persistence. This webinar gives an overview on how to benefit from SAP HANA in existing and new custom development based on SAP NetWeaver AS ABAP 7.0x and 7.4.

Speaker - Eric Westenberger, SAP

Start : May 1, 2013 1:00 PM (CT), 2:00 PM (ET), 12:00 PM (MT), 11:00 AM (PT)

End: May 1, 2013 2:00 PM (CT), 3:00 PM (ET), 1:00 PM (MT), 12:00 PM (PT)

Registration Link

http://www.asug.com/events/detail/Custom-ADAP-Development-on-SAP-HANA

or Click Here

Please register soon. This is the first of our webcast series on SAP Development Technologies.

Be sure not to miss! Note that this session is for ASUG Members only.

Thanks,

Srini

Srini Tanikella,

ASUG BITI/ Development Technologies SIG Chair